; Script generado para instalaciones con inno setup, son solo una guia para el programador.

; Definimos las constantes con el nombre de la aplicación
; Nombre con versión, Fabricante y nombre del ejecutable
#define MyAppName “NetSend2007”
#define MyAppVerName “NetSend 2007 2.0.0”
#define MyAppPublisher “Jgoh”
#define MyAppExeName “red.exe”

; Asignamos caracteristicas al instalador

[Setup]
; Nombre de la aplicacion
AppName={#MyAppName}

; Versión de la aplicación
AppVerName={#MyAppVerName}

; Fabricante
AppPublisher={#MyAppPublisher}
AppCopyright=José Guillermo Ortiz Hernández

; Carpeta destino de la aplicación
DefaultDirName={pf}\{#MyAppName}

; Nombre del grupo de programas en el menú inicio
DefaultGroupName={#MyAppName}

; Carpeta donde se encuentra las archivos (permite especificar los archivos de forma relativa)
SourceDir=D:\jgoh\netsend

; Donde se guardara el instalador
OutputDir=Instalador

; Nombre base para el instalador
OutputBaseFilename=Instalador NetSend

; Icono para el instalador
SetupIconFile=ico\email.ico

; Tipo de compresión poara los archivos
Compression=lzma

; Indica si la compresión es solida
SolidCompression=true

; Información adicional de version y fabricante
VersionInfoVersion=1.0
VersionInfoCompany=José Guillermo Ortiz Hernández
VersionInfoCopyright=José Guillermo Ortiz Hernández
VersionInfoDescription=Software para la mensajeria en una intranet LAN
VersionInfoTextVersion=NetSend 2007 2.0.0 Plus

; Este archivo contiene informacion del instalador, archivos tamaños y compresión
OutputManifestFile=manifiesto.txt

; Versión Minima de sistema operativo para instalar la aplicación
MinVersion=4.90.3000,5.01.2600

; Privilegios de usuario
PrivilegesRequired=admin

; Informacion de la pagina
UserInfoPage=true

; Avisar si el directorio existe
DirExistsWarning=no

; Mostrar la ventana de dialogo
ShowLanguageDialog=yes

; Versión del instalador
AppVersion=1.0

; Identificador de instalación
AppID={{77BE939D-F12B-4A3F-8884-2AF2A2716E97}

; Ubicación del desInstalador
UninstallFilesDir={app}/quitar

; Icono para el desInstalador
UninstallDisplayIcon={app}\ico\email.ico

; Imagenes en el instalador
WizardImageFile=iss\install.bmp
WizardSmallImageFile=iss\install small.bmp

; Nombre con el que aparece para desInstalar en la opción “Agregar o quitar programas”
UninstallDisplayName=NetSend2007 (Quitar)

; Idioma del instalador
; Se define el nombre como español, para los mensajes del compilador, el archivo de idioma se encuentra en la carpeta
; lenguales en el directorio de Inno Setup
[Languages]
Name: spanish; MessagesFile: compiler:Languages\Spanish.isl

; Tareas a realizar
; El nombre de la tareas es destopicon y crea un icono en el escritorio, la tarea no esta seleccionada
; por defecto y un componente del tipo de instalación aplicación
[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked; Components: aplicación

; Archivos
; Son las rutas de los archivos, notece que el origen se trabaja con ruta relativo, esto debido a que en la seccion [SETUP]
; se establece la propiedad SourceDir=D:\jgoh\netsend lo que indica que todos los archivos de origen se encuentran en esta
; carpeta.
; El origen se inicia con la etiqueta “Source”, seguida por el nombre, la carpeta de destino. Los flags son parametros adicionales
; que indican una característica especial.
[Files]
Source: red.exe; DestDir: {app}; Flags: ignoreversion; Components: aplicación
Source: dat\*; DestDir: {app}\dat; Flags: ignoreversion recursesubdirs createallsubdirs; Components: aplicación
Source: wav\*; DestDir: {app}\wav; Flags: ignoreversion recursesubdirs createallsubdirs; Components: aplicación

; Para esta aplicación los iconos no se extraen de un ejecutable si no que se usan como objeto .Ico
;Iconos
Source: ico\email.ico; DestDir: {app}\ico; Flags: ignoreversion recursesubdirs createallsubdirs; Components: aplicación
Source: ico\attached.ico; DestDir: {app}\ico; Flags: ignoreversion recursesubdirs createallsubdirs; Components: aplicación
Source: ico\help.ico; DestDir: {app}\ico; Flags: ignoreversion recursesubdirs createallsubdirs; Components: aplicación

; Una característica que incluye esta aplicación es un icono en la bandeja del sistema, este icono maneja un menú el cual no se ejecuta si no
; existe el archivo mnx, así que este es copiado del origen a una carpeta en el destino.
; Menú systray
Source: mnx\systray.*; DestDir: {app}\mnx; Components: aplicación

; Archivos de ayuda
; Esta aplicación maneja archivos de ayuda tipo window (*.hlp), también abrian podido se tipo (*.chm), pero para este caso son
; son necesarios los archivos .hlp, gid y cnt, los dos ultimos son opcionales, ya que si no existen el gestor de ayuda los crea
Source: hlp\netsend2007.hlp; DestDir: {app}\hlp; Components: aplicación runtime
Source: hlp\netsend2007.GID; DestDir: {app}\hlp; Components: aplicación runtime
Source: hlp\netsend2007.cnt; DestDir: {app}\hlp; Components: aplicación runtime

; librerías adicionales
; Esta aplicación utiliza dos librerías ( aunzip32.dll y azip32.dll) para crear archivos zip
; Esta librerías deben ser copiadas en C:\Windows\System32 solo si no existen y son componentes del
; tipo de instalación runtime
Source: runtime\aunzip32.dll; DestDir: {sys}; Flags: onlyifdoesntexist; Components: runtime
Source: runtime\azip32.dll; DestDir: {sys}; Flags: onlyifdoesntexist; Components: runtime
Source: runtime\msvcr70.dll; DestDir: {sys}; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\msvcr71.dll; DestDir: {sys}; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime

; Librerías de Visual FoxPro Sp1
; En system32
Source: runtime\vfp9r.dll; DestDir: {sys}; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\vfp9resn.dll; DestDir: {sys}; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\vfp9t.dll; DestDir: {sys}; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime

; En Microsoft Shared
Source: runtime\vfp9t.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\vfp9resn.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\vfp9r.dll; DestDir: {cf}\Microsoft Shared\VFP; Flags: onlyifdoesntexist uninsneveruninstall; Components: runtime

; Componenetes Active X
; Estos componenetes probben de caracteristicas especiales a nuestras aplicaciones, caracteristicas que van desde
; interpretar archivos RTF hasta comunicarse con otro equipo por TCP/UDP
Source: runtime\comctl32.ocx; DestDir: {sys}; Flags: sharedfile regserver onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\mschrt20.ocx; DestDir: {sys}; Flags: sharedfile regserver onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\mscomct2.ocx; DestDir: {sys}; Flags: sharedfile regserver onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\MSCOMCTL.OCX; DestDir: {sys}; Flags: sharedfile regserver onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\MSMAPI32.OCX; DestDir: {sys}; Flags: sharedfile regserver onlyifdoesntexist uninsneveruninstall; Components: runtime
Source: runtime\richtx32.ocx; DestDir: {sys}; Flags: sharedfile regserver onlyifdoesntexist uninsneveruninstall; Components: runtime

; Acontinuacion creamoslos accesos directosa nuestra aplicación o a sus componenets

[Icons]
Name: {group}\{#MyAppName}; Filename: {app}\{#MyAppExeName}; WorkingDir: {app}; IconFilename: {app}\ico\email.ico; IconIndex: 0; Components: aplicación

Name: {userdesktop}\{#MyAppName}; Filename: {app}\{#MyAppExeName}; Tasks: desktopicon; WorkingDir: {app}; IconFilename: {app}\ico\email.ico; IconIndex: 0; Components: aplicación

Name: {group}\Ayuda NetSend2007; Filename: {app}\hlp\netsend2007.hlp; WorkingDir: {app}; IconFilename: {app}\ico\help.ico; IconIndex: 0; Components: aplicación

Name: {group}\Carpeta adjuntos; Filename: explorer; Parameters: “””{app}\adjuntos”””; WorkingDir: {app}; IconFilename: {app}\ico\attached.ico; IconIndex: 0; Comment: Explora la carpeta de adjuntos; Components: aplicación

; Aqui le indicamos al compilador que despues de instalar la aplicación la ejecute
[Run]
Filename: {app}\{#MyAppExeName}; Description: {cm:LaunchProgram,{#MyAppName}}; Flags: nowait postinstall skipifsilent; WorkingDir: {app}; Components: aplicación

; Para esta aplicación es necesario que en la carpeta exista un asubcarpeta para almacenar los datos adjuntos
; así que con la etiqueta DIRS creamos estos subdirectorios
[Dirs]
Name: {app}\adjuntos; Tasks: ; Languages: ; Components: aplicación
Name: {drive:{src}}\temp; Components: aplicación

; El registro de Windows es una herramienta muy útil para un programador, ya que en esta se puede almacenar
; muchas caracteristicas del software
[Registry]
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: RecordarUsuario; ValueData: .T.; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: Usuario; ValueData: ADMIN; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: bandeja_toolbarDock; ValueData: 0; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: bandeja_mensajes_toolbarDock; ValueData: 1; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: oleInformacionView; ValueData: 3; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: redactar_toolbarDock; ValueData: 0; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: frmRedactarLeft; ValueData: 0; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: frmRedactarTop; ValueData: 0; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: frmRedactarWindowState; ValueData: 0; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: spnTiempo; ValueData: 2; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: txtSonido; ValueData: {app}\WAV\EJEMPLO2.WAV; Flags: uninsdeletekey; Components: runtime aplicación
Root: HKCU; SubKey: Software\JGOH\NetSend; ValueType: string; ValueName: Auto; ValueData: .F.; Flags: uninsdeletekey; Components: runtime aplicación

; Los tipos de instalación le indican al instalador que hacer que copiar y que no, así por ejemplo el usuario en este caso puede escojer RUNTIME
; Tipo de instalación que solo copiara en disco los archivos necesarios para ejecutar aplicaciones
[Types]
Name: Completa; Description: Completa
Name: Runtime; Description: Runtime; Languages:

[Components]
Name: runtime; Description: runtime; Types: Runtime Completa
Name: aplicación; Description: aplicación; Types: Completa

---

---

 

🦋 Siguenos tambien en Bluesky, el nuevo Twitter de los creadores de Twitter

---